1 '┌──────────────────────────────┐
2 '│ *ALCATRAZ* A fuga impossivel │
3 '│                              │
4 '│  de Wilson Fazzio Martins    │
5 '│                              │
6 '│ English version: MarMSX 2017 │
7 '└──────────────────────────────┘
10 COLOR15,1,1: SCREEN 2,0
20 OPEN"GRP:"FOR OUTPUT AS #1
100 CLEAR4000:DEFINTA-Z:COLOR8,15,15
110 SCREEN2,0:OPEN"GRP:"AS#1
120 VPOKE6144,1:VPOKE6400,1:VPOKE6656,1
130 FORN=0TO7:READQ$:Q=VAL("&H"+Q$)
140 VPOKEN,Q:VPOKEN+2048,Q:VPOKEN+4096,Q:NEXT
150 FORN=0TO7:READQ$:Q=VAL("&H"+Q$)
160 VPOKEN+8192,Q:VPOKEN+10240,Q:VPOKEN+12288,Q:NEXT
170 GOSUB3030
180 DEFFNS$(J)=MID$(SU$(J),3)
190 DIMPO$(13,11):FORM=2TO11:FORN=0TO13:READPO$(N,M):NEXTN:NEXTM
200 NS=34:DIMSU$(NS):FORN=0TONS:READSU$(N):NEXT
210 NV=23:DIMVE$(NV):FORN=0TONV:READVE$(N):NEXT
220 NA=54:AS=44:DIMAC$(NA):FORN=0TONA:READAC$(N):NEXT
230 PC=8:PL=7:ED=6611:COLOR1,5,5:CLS
240 FORN=0TO14:VPOKE6144+N,15:VPOKE6400+N,15:VPOKE6656+N,15:NEXT
250 FORN=0TO119:READQ$:Q=VAL("&H"+Q$)
260 VPOKEN,Q:VPOKEN+2048,Q:VPOKEN+4096,Q:NEXT
270 FORN=0TO119:READQ$:Q=VAL("&H"+Q$)
280 VPOKEN+8192,Q:VPOKEN+10240,Q:VPOKEN+12288,Q:NEXT
290 GOSUB1390
300 STOPON:ONSTOPGOSUB2990
310 GOTO690
320 REM
330 REM   ♦♦♦♦♦ WAITS FOR MOVEMENT ♦♦♦♦♦
340 I$=INKEY$:IFI$=""THEN340
350 GOSUB1390
360 IF(I$>="A"ANDI$<="Z")OR(I$>="a"ANDI$<="z")THENFR$="":I=0:PSET(16,8),15:GOTO970
370 MO=0:Q=ASC(I$)
380 IFQ=24THEN820
390 IFQ=27THEN890
400 IFQ=38THENSTOP
410 Q=STICK(0)
420 IFQ=1THENMO=1
430 IFQ=5THENMO=2
440 IFQ=3THENMO=3
450 IFQ=7THENMO=4
460 IFMO=0THEN340
470 I$=MID$(PO$(PC,PL),MO,1)
480 REM
490 REM  ♦♦♦♦ LOCAL MESSAGES ♦♦♦♦
500 IFI$="0"THEN690
510 IFI$="1"THEN340
520 IFI$="2"THENPRINT#1,"The bars block your way.":GOTO340
530 IFI$="3"THENPRINT#1,"The officer is here and he      doesn't let you go.":GOTO340
540 IFI$="4"THENPRINT#1,"There is a electric chair here. You died."
550 IFI$="5"THENPRINT#1,"There is a closed door here.":GOTO340
560 IFI$="6"ANDX(7)=1ANDLEFT$(SU$(6),1)="*"THEN690
570 IFI$="6"THENPRINT#1,"It is too dark here. You've     stumbled and broken your leg."
580 IFI$="7"THENPRINT#1,"You were burned by the          remaining fire. Bad way to die!"
590 IFI$="8"THENPRINT#1,"You triggered the alarm! You've been caught! You were fusilladed"
600 IFI$="9"THENPRINT#1,"You passed through a light beam triggering another alarm!"
610 IFI$="A"ANDX(9)=1ANDLEFT$(SU$(15),1)="*"THENPRINT#1,"The dogs sleep...":GOTO690
620 IFI$="A"THENPRINT#1,"There are five dogs here. You   have been terrible gobbled up!"
630 IFI$="B"THENPRINT#1,"The passage here is blocked by  earth.":GOTO340
640 IFI$="C"THENPRINT#1,"You found the jailor and he     denounced you."
650 IFI$="D"THENPRINT#1,"We escaped from the building,   but it remains the outside...":GOTO690
660 GOTO1430
670 REM
680 REM ♦♦♦♦♦ DRAW THE MAZE ♦♦♦♦♦♦
690 IFMO=1THENPL=PL-1
700 IFMO=2THENPL=PL+1
710 IFMO=3THENPC=PC+1
720 IFMO=4THENPC=PC-1
730 IFED=6613 OR ED=6677 OR ED=6741 THEN VPOKEED,6 ELSE VPOKEED,0
740 I$=PO$(PC,PL):ED=BASE(10)+PC*2+PL*64+3:VPOKEED-33,1:VPOKEED-31,1:VPOKEED+31,1:VPOKEED+33,1:VPOKEED,14
750 VPOKEED-32,VAL("&H"+MID$(I$,1,1))
760 VPOKEED+32,VAL("&H"+MID$(I$,2,1))
770 VPOKEED+1,VAL("&H"+MID$(I$,3,1))
780 VPOKEED-1,VAL("&H"+MID$(I$,4,1))
790 X(6)=0:X(8)=0:SOUND8,0:GOTO340
800 REM
810 REM ♦♦ SHOWS LOCAL OBJECTS ♦♦♦
820 PRINT#1,"There is here: ";:I$=CHR$(PC+60)+CHR$(PL+60)
830 M=0:FORN=0TONS
840 IFI$=LEFT$(SU$(N),2)THENPRINT#1,MID$(SU$(N),3);" ";:M=1
850 NEXT:IFM=0THENPRINT#1,"Nothing important";
860 GOTO340
870 REM
880 REM ♦♦SHOWS PLAYER OBJECTS♦♦
890 PRINT#1,"You have: ";:I$="**":GOTO830
900 REM
910 REM ♦♦♦ INPUT USER TEXT COMMANDS ♦♦♦♦
920 I$=INKEY$:IFI$=""THEN920
930 PSET(I*8+16,8),15
940 IFASC(I$)=8ANDI>0THENI=I-1:FR$=LEFT$(FR$,I):LINE(8*I+16,8)-(8*I+23,15),15,BF:GOTO920
950 IFASC(I$)=13THEN1010
960 Q=STICK(0):IFQ<>0THENGOSUB1390:GOTO 420
970 IF I$>="a" AND I$<="z" THEN I$=CHR$(ASC(I$)-32)
980 IF(I$<"A"ORI$>"Z")ANDI$<>" "THEN920
990 PRINT#1,I$;:FR$=FR$+I$:I=I+1:IFI=30THEN1010
1000 GOTO920
1010 GOSUB1390:IFFR$=""THENGOTO340
1020 FORN=LEN(FR$)TO1STEP-1:IFMID$(FR$,N,1)=" "THENNEXT
1030 FR$=LEFT$(FR$,N)
1040 FORN=1TOLEN(FR$)
1050 IFMID$(FR$,N,1)<>" "THENNEXT
1055 IF LEFT$(FR$,N-1)="GO" OR LEFT$(FR$,N-1)="TURN" THEN NEXT
1060 FORM=0TONV
1070 IFVE$(M)=LEFT$(FR$,N-1)THENI$=CHR$(M+50):GOTO1100
1080 NEXTM
1090 PRINT#1,"What is ";LEFT$(FR$,N);" ?":GOTO340
1100 IFLEN(FR$)=N-1THEN1230 ELSE FR$=MID$(FR$,N+1):FORN=1TOLEN(FR$)
1110 IFMID$(FR$,N,1)<>" "THENNEXT
1120 FORM=0TONS
1130 IFFNS$(M)=LEFT$(FR$,N-1)THENI$=I$+CHR$(M+50):GOTO1150
1140 NEXTM:GOTO1090
1150 IFLEN(FR$)=N-1THEN1230 ELSE FR$=MID$(FR$,N+1)
1160 FORN=LEN(FR$)TO1STEP-1
1170 IFMID$(FR$,N,1)<>" "THENNEXT
1180 FORM=0TONS
1190 IFFNS$(M)=MID$(FR$,N+1)THENI$=I$+CHR$(M+50):GOTO1230
1200 NEXTM:PRINT#1,"What is ";MID$(FR$,N+1);" ?":GOTO340
1210 REM
1220 REM ♦♦♦ CODE ACTION IN I$♦♦♦
1230 P$=CHR$(PC+60)+CHR$(PL+60)
1240 IFLEN(I$)<>1THENGOSUB1520
1250 FORN=0TOAS
1260 IFI$=AC$(N)THEN1330
1270 NEXT
1280 IFLEN(I$)=1THEN1320
1290 FORN=AS+1TONA
1300 IFLEFT$(I$,1)=AC$(N)THEN1330
1310 NEXT
1320 PRINT#1,"This is not possible.":GOTO340
1330 ON(N+1)GOSUB1620,1630,1630,1650,1660,1660,1660,1670,1680,1700,1720,1730,1740,1770,1790,1700,1800,1820,1840,1860,1890,1910,1930,1940,1970,1990,2010,2030,2060,1630
1340 IF N<30 THEN 340
1350 ON(N-29)GOSUB1630,1620,2100,2160,2170,2180,2190,2200,2960,2230,2240,2260,2270,2280,2310,2330,2370,2450,2520,2610,2650,2740,2760,2920,2940
1360 GOTO340
1370 REM
1380 REM ♦ ERASE 3 UPPER LINES ♦
1390 LINE(0,8)-(255,23),15,BF
1400 PSET(0,8),15:RETURN
1410 REM
1420 REM ♦♦♦♦♦♦♦ GAME OVER ♦♦♦♦♦♦♦♦
1430 SOUND7,56:PLAY"T200O2L8S0M8000F2F4.FF2G+4.GG4.FF4.EF2"
1440 FORN=1TO6000:NEXT:GOSUB1390:PRINT#1,"Play again (Y/N) ?"
1450 I$=INKEY$
1460 IFI$="Y"ORI$="y"THENRUN
1470 IFI$="N"ORI$="n"THENNEW
1480 IFI$="W"THEN340
1490 GOTO1450
1500 REM
1510 REM ♦♦ CHECK FOR REFERENCED OBJECTS ♦♦
1520 J=ASC(MID$(I$,2,1))-50:IFLEFT$(SU$(J),2)=P$ OR LEFT$(SU$(J),2)="**" OR LEFT$(SU$(J),2)=".." OR LEFT$(I$,1)=">" OR LEFT$(I$,1)="9" THEN 1540
1530 I=J:GOTO1560
1540 IF LEN(I$)<3 THEN RETURN
1550 I=ASC(MID$(I$,3,3))-50:IF LEFT$(SU$(I),2)=P$ OR LEFT$(SU$(I),2)="**" OR LEFT$(SU$(I),2)=".." THEN RETURN
1560 PRINT#1,"I'm not seeing ";FNS$(I):GOTO340
1570 REM
1580 REM ♦♦ DELETE REFERENCED OBJECT ♦♦
1590 SU$(J)="  "+FNS$(J):RETURN
1600 REM
1610 REM ♦♦♦♦ ACTION SUB-ROTINES ♦♦♦♦
1620 PRINT#1,"More than they are ?":RETURN
1630 PRINT#1,"Ok. It turned to stripes."
1640 X(1)=0:X(0)=0:SU$(1)="**"+FNS$(1):GOTO 1590
1650 PRINT#1,"Ok, but this is a waste.":GOTO 1590
1660 PRINT#1,"Ok, it did't seem really useful.":GOTO 1590
1670 PRINT#1,"Ok, but I don't understand why  you did that.":GOTO 1590
1680 PRINT#1,"The ";MID$(SU$(J),3);" turned to a ";FNS$(2);"!"
1690 SU$(2)="**"+FNS$(2):GOTO 1590
1700 PRINT#1,"Ok, it reaches the bottom."
1710 X(0)=1:SU$(J)=P$+FNS$(J):RETURN
1720 PRINT#1,"Not possible, the ";FNS$(I);" is made  of bricks.":RETURN
1730 PRINT#1,"Ok...":RETURN
1740 IFX(1)=0 OR P$<>"CC" THEN PRINT#1,"Nothing happens.":RETURN
1750 PRINT#1,"The keys came with it!"
1760 SU$(3)="**"+FNS$(3):RETURN
1770 PRINT#1,"The food wasn't good... Maybe   without seasoning."
1780 GOTO 1590
1790 PRINT#1,"Are you insane? Needs a         psychiatrist? I won't do it.":RETURN
1800 PRINT#1,"Looks tidy..."
1810 SU$(J)=P$+FNS$(J):RETURN
1820 PRINT#1,"Ok. Now I think it gonna work."
1830 X(2)=1:GOTO 1590
1840 PRINT#1,"It fits perfectly."
1850 X(3)=1:GOTO 1590
1860 IFP$<>"?F" AND P$<>"B@" THEN PRINT#1,"I can't see a door.":RETURN
1870 IFP$="B@" THEN PRINT#1,"There is no space to put it.":RETURN
1880 X(4)=1:PRINT#1,"It fitted on door.":SU$(J)=P$+FNS$(J):RETURN
1890 PRINT#1,"It blocked the fire!":SU$(J)=P$+FNS$(J):SU$(I)="JJ"+FNS$(I)
1900 PO$(PC,PL)="0000":VPOKEED-32,0:GOTO3240
1910 SOUND7,7:SOUND8,16:SOUND6,0:SOUND13,0:SOUND12,50:FORQ=0TO1400:NEXT
1920 PRINT#1,"The place was invaded by smoke  and you died suffocated!":GOTO 1430
1930 PRINT#1,"Ok...":X(5)=1:GOTO1590
1940 SOUND7,56:SOUND8,14:SOUND1,5:FORQ=0TO255:SOUND0,Q:NEXT:SOUND8,0
1950 PRINT#1,"You did it! You turned off the  alarm!"
1960 PO$(PC,PL)="1000":SU$(I)="JJ"+FNS$(I):VPOKEED-1,0:GOTO1590
1970 PRINT#1,"Now it's ready to work."
1980 X(6)=1:RETURN
1990 SOUND7,56:PLAY"V13L32AO7BO2CO5DO1EO8FO4G":FORQ=0TO1000:NEXT
2000 PRINT#1,"Short circuit!":PO$(PC,PL)="0011":VPOKEED-32,0:SU$(I)="JJ"+FNS$(I):GOSUB1590:GOTO2970
2010 IFX(2)=0 THEN PRINT#1,"It doesn't work...":RETURN
2020 PRINT#1,"It is on.":X(7)=1:RETURN
2030 IFX(6)=0 THEN PRINT#1,"It won't start...":RETURN
2040 PRINT#1,"It is on.":X(8)=1
2050 SOUND7,56:SOUND1,15:SOUND8,16:SOUND13,14:SOUND12,10:RETURN
2060 IFX(3)=0 THEN PRINT#1,"I think it's broken... It doesn't work anyway.":RETURN
2070 IFX(5)=0 THEN PRINT#1,"There is one thing missing to   hear music on the recorder...":RETURN
2080 BEEP:PLAY"O3L4S0M5000C2CDE2.EFEDCD2.FF2GFE2CEDCCO2BO3C","O6L4V7E2DCD2.EFEFED2.FF2EDE2DCDDEDC"
2090 PRINT#1,"It plays a soft music... I      think I gonna sleep...":X(9)=1:RETURN
2100 IFP$<>"B@" AND P$<>"?F" THEN PRINT#1,"Where is the door?":RETURN
2110 IFP$="?F" OR X(8)=0 OR X(6)=0 THEN PRINT#1,"It is off.":RETURN
2120 SOUND7,56:SOUND8,15:SOUND9,15:SOUND1,2:SOUND3,7:SOUND0,255:SOUND2,255:FORQ=1TO500:NEXT:SOUND1,0:SOUND3,5
2130 FORQ=1TO1000:NEXT:BEEP
2140 PRINT#1,"The ";FNS$(J);" has fallen to pieces."
2150 PO$(PC,PL)="0011":VPOKEED-32,0:RETURN
2160 PRINT#1,"Ok...":X(6)=0:SOUND8,0:RETURN
2170 PRINT#1,"It is out.":X(2)=0:X(7)=0:SU$(J)="**"+FNS$(J):RETURN
2180 PRINT"Ok...":X(5)=0:X(9)=0:SU$(J)="**"+FNS$(J):RETURN
2190 PRINT#1,"Ok... But what you gonna do withit?":X(3)=0:X(9)=0:SU$(J)="**"+MID$(SU$(J),3):RETURN
2200 SOUND7,7:SOUND6,10:SOUND8,16:SOUND13,12:SOUND12,10:FORQ=0TO2500:NEXT:SOUND8,0:VPOKEED+32,0
2210 PRINT#1,"A hole was opened."
2220 PO$(PC,PL)="0010":GOTO1590
2230 PRINT#1,"It's in your body. It fits      perfectly!":RETURN
2240 IFX(0)=0THENPRINT#1,"You fell directly to the         bottom. Instant death.":GOTO1430
2250 GOTO3010
2260 PRINT#1,"The water was not pure. You     died contaminated.":GOTO1430
2270 PRINT#1,"You got drunk and surrendered   yourself. Lack of intelligence.":GOTO 1430
2280 IFP$="CC" THEN PRINT#1,"Opened!";:PO$(PC,PL)="1100":VPOKEED-1,0:GOTO3240
2290 IFP$="EB" THEN PRINT#1,"Opened again!":PO$(PC,PL)="0610":VPOKEED-1,0:GOTO3240
2300 PRINT#1,"I cant' see the bars.":RETURN
2310 IFP$="B@" OR P$="?F" THEN PRINT#1,"It is locked.":RETURN
2320 PRINT#1,"There is no door nearby.":RETURN
2330 IFLEN(I$)=2 THEN PRINT#1,"To whom?":RETURN ELSE IF I<>22 AND I<>25 AND I<> 30 THEN PRINT#1,"Are you crazy? Why don't you    talk to a person?":RETURN
2340 IFI$<>">2H" OR P$<>"CC" THEN PRINT#1,"He listened you, but did nothing.":RETURN
2350 PRINT#1,"He answerd your request and left,dropping the keys outside..."
2360 SU$(I)="CD"+FNS$(I):SU$(J)=P$+FNS$(J):RETURN
2370 IF I$="?>S" THEN GOTO 1990
2380 IF I$="?>N" THEN GOTO 1910
2390 IF I$="?=N" THEN GOTO 1890
2400 IF I$="?4O" THEN GOTO 1700
2410 IF J<22 AND J<>2 THEN PRINT#1,"You lost the object.":GOTO1590
2420 IF J>21 THEN PRINT#1,"You are not that strong...":RETURN
2430 IF P$<>"CC" THEN PRINT#1,"Nothing happens...":RETURN
2440 IF LEFT$(SU$(22),2)="CD" THEN PRINT#1,"The rope reached an object      outside. I can't see what it is.":X(1)=1:RETURN ELSE PRINT#1,"Nothing happend yet...":RETURN
2450 IF I<>9 THEN PRINT#1,"With what?!":RETURN
2460 IF J>21 THEN PRINT#1,"It's not possible to do it.":RETURN
2470 IF J=10 AND X(4)=1 THEN GOTO2490
2480 PRINT#1,"It fell to ashes...":GOTO1590
2490 SOUND7,7:SOUND6,30:SOUND8,16:SOUND13,5:SOUND12,30:VPOKEED-32,0
2500 FORQ=0TO2000:NEXT
2510 PRINT#1,"The ";FNS$(28);" opened a way!":PO$(PC,PL)="0011":RETURN
2520 IF J>21 THEN PRINT#1,"Not possible.":RETURN
2530 Q=0:FORN=0TONS:IFLEFT$(SU$(N),1)="*"THENQ=Q+1
2540 NEXT
2550 IFQ>5THENPRINT#1,"Hands full. I can't take        anything else.":RETURN
2560 IF LEFT$(SU$(J),1)="*" THEN PRINT#1,"You already carry that object.":RETURN
2570 SU$(J)="**"+FNS$(J):PRINT#1,"Ok."
2580 IF J=2 THEN X(0)=0
2590 IF J+10 THEN X(4)=0
2600 RETURN
2610 IF LEFT$(SU$(J),1)<>"*" THEN PRINT#1,"You don't carry the ";FNS$(J):RETURN
2620 PRINT#1,"It's on the floor."
2630 SU$(J)=P$+FNS$(J)
2640 RETURN
2650 IF I<>22 AND I<>25 AND I<>30 AND I<>32 THEN PRINT#1,"I think the prision affected    your IQ.":RETURN
2660 IF I$="CCR" THEN PRINT#1,"The dogs ate your arm. The      escape now is impossible.":GOTO1430
2670 IF I$="C2K" THEN PRINT#1,"He accepted and gave you money  in return!":SU$(5)="**"+FNS$(5):GOTO1590
2680 IF I$="C7H" THEN PRINT#1,"He accepted and let you go.":SU$(5)="IG"+FNS$(5):SU$(22)="JJ"+FNS$(22):VPOKEED+32,0:PO$(PC,PL)="1040":GOTO3240
2690 IF I$="C7P" THEN PRINT#1,"He don't accept bribes. You     have been killed.":GOTO 1430
2700 IF I$="CDP" THEN PRINT#1,"He accepted and leaved!":PO$(PC,PL)="1001":VPOKEED+1,0:GOSUB3240:GOTO1590
2710 IF LEFT$(SU$(J),1)<>"*" THEN PRINT#1,"But you don't carry this object!":RETURN
2720 PRINT#1,"He accepted, but nothing        happened."
2730 GOTO1590
2740 IF J<>22 AND J<>25 AND J<>30 AND J<>32 THEN PRINT#1,"You place is not here, but in    the asylum.":RETURN
2750 PRINT#1,"You have been killed before you could do something.":GOTO 1430
2760 IF J=7 THEN PRINT#1,"It is electric and powerful.":RETURN
2770 IF J=8 THEN PRINT#1,"The voltage is 1,5.":RETURN
2780 IF J=9 THEN PRINT#1,"The box is full.":RETURN
2790 IF J=11 THEN PRINT#1,"E' bem grosso.":RETURN
2800 IF J=14 THEN PRINT#1,"It is a music tape.":RETURN
2810 IF J=15 THEN PRINT#1,"It is cassette recorder.":RETURN
2820 IF J=19 THEN PRINT#1,"It is made of rubber.":RETURN
2830 IF J=20 THEN PRINT#1,"It is Budweiser":RETURN
2840 IF J=23 THEN PRINT#1,"It is made of bricks.":RETURN
2850 IF J=24 THEN PRINT#1,"It is made of resistant steel.":RETURN
2860 IF J=26 THEN PRINT#1,"The voltage is 110.":RETURN
2870 IF J=28 THEN PRINT#1,"You burned yourself! You shouldnot have examined it!":GOTO 1430
2880 IF J=29 THEN PRINT#1,"It is too deep. I can't see the bottom.":RETURN
2890 IF J=32 THEN PRINT#1,"They are police dogs.":RETURN
2900 IF J=22 OR J=25 OR J=30 THEN PRINT#1,"You have been killed. He doesn'tlike to be examined.":GOTO 1430
2910 PRINT#1,"It is common.":RETURN
2920 IF J<>22 AND J<>25 AND J<>30 AND J<>32 THEN PRINT#1,"Only a person with your         mentality should say that thing.":RETURN
2930 PRINT#1,"You have been killed. He doesn'tlike to be examined.":GOTO 1430
2940 IF J<22 THEN PRINT#1,"Ok... Done...":GOTO1590
2950 PRINT#1,"Not possible.":RETURN
2960 PRINT#1,"Ok..."
2970 SOUND7,7:SOUND8,16:SOUND13,0:SOUND6,28:SOUND12,20:RETURN
2980 GOTO 2960
2990 BEEP:PLAY"V15L1O3E","V15L1O3B":FORE9=0TO2000:NEXT:BEEP
3000 RETURN
3010 GOSUB1390:PRINT#1,"You escaped through a secret    passageway! You left ALCATRAZ!":SOUND7,56
3020 PLAY"T120L4O5V9EEFGGFEDCCDEE.D8D2EEFGGFEDCCDED.C8C2":GOTO3020
3030 READX,Y
3032 COLOR1:PSET(45,65),15:PRINT#1,"Escape from":COLOR8
3040 FORN=0TO65:READA,B:LINE(X,Y)-(A,B):X=A:Y=B:NEXT
3050 LINE(20,114)-(208,114)
3060 FORN=1TO8:READA
3070 PAINT(A,80):NEXT
3075 PSET(8,8),15:PRINT#1,"Programmed by Wilson F. Martins"
3080 PSET(50,170),15:PRINT#1,"Push SPACE to begin."
3090 IFSTRIG(0)=0THEN3090
3095 LINE(0,8)-(255,15),15,BF:LINE(28,170)-(255,177),15,BF
3100 FORN=0TO9:VPOKE6370+N*35,0
3110 SOUND7,7:SOUND8,16:SOUND6,25:SOUND13,0:SOUND12,20
3120 FORM=0TO100:NEXTM,N:RETURN
3130 DATA 10,41,18,3C,3C,19,40,01
3140 DATA 10,10,10,10,10,10,10,10
3150 DATA44,78,44,78,16,114,28,114,36,103,36,114,44,114,44,78
3160 DATA 48,78,48,114,72,114,64,106,64,106,56,106,56,78,48,78
3170 DATA 72,78,72,114,96,114,88,106,80,106,80,86,88,86,96,78,72,78
3180 DATA 124,78,96,114,108,114,116,103,116,114,124,114,124,78
3190 DATA 124,78,132,86,136,86,136,114,144,114,144,86,148,86,156,78,124,78
3200 DATA 156,78,156,114,164,114,164,98,172,114,180,114,172,98,180,98,172,78,156,78
3210 DATA208,78,180,114,192,114,200,103,200,114,208,114,208,78
3220 DATA 208,78,240,78,224,106,232,106,240,114,208,114,224,86,216,86,208,78
3230 DATA 43,49,73,123,127,159,207,220
3240 SOUND7,56:PLAY"O4V13L32CFB":RETURN
3250 REM
3260 REM ♦ MAZE DATA ♦
3270 DATA 1001,1010,1001,1100,1100,1009,1100,1100,1100,1100,1010,10C1,1100,1010
3280 DATA 0011,0011,0101,1100,1010,0011,1001,1010,1011,1011,0011,0101,1010,0011
3290 DATA 0011,0011,1101,1100,0110,0011,5011,0101,0110,0011,0011,1011,0011,0011
3300 DATA 0011,0011,1001,1000,1010,8011,0001,1100,1100,0010,0011,0011,0011,0011
3310 DATA 0111,0101,0010,0011,0011,0011,0011,1101,1100,0612,0011,0101,0010,0011
3320 DATA 1001,1010,0011,0011,0011,0011,0001,1102,1110,6611,0011,1011,0011,0111
3330 DATA 0011,0011,0111,0011,0101,0110,0101,1340,1111,6611,0011,0101,0100,1010
3340 DATA 0011,0011,1001,7000,1010,1101,1100,0100,1010,6111,0011,1001,1100,0B10
3350 DATA 0011,0011,0011,5011,0101,1100,1100,1110,0011,1001,0110,0011,1001,0110
3360 DATA 0111,0101,0110,0101,1100,1100,1100,1100,0110,01A1,11DA,0110,0101,1110
3370 REM
3380 REM ♦♦♦ NOUNS ♦♦♦
3390 DATA JJFOOD,JJSTRIPES,JJROPE,JJKEYS,DCSHEET,IGMONEY,AEFLASHLIGHT,"E?SAW","D?BATTERY",EEMATCHES,AGNEWSPAPER,CBBLANKET,<GWATER,AEREVOLVER,<BTAPE,>@RECORDER,G@SHOVEL,>DBONE,"D?CARDS",FACLOTHES,GCBEER,CFMIRROR
3400 DATA CCOFFICER,DCBED,..BARS,CBPRISIONER,B@PLUG,..DOOR,"?EFIRE",ICWELL,G>JAILOR,IEEARTH,EGDOGS,AAALARM,A>LIGHT
3410 REM
3420 REM ♦♦♦ VERBS ♦♦♦
3430 DATA TEAR,TIE,PULL,EAT,PUT,"TURN ON",CUT,REMOVE,DIG,SHOOT,WEAR,"GO INTO",ASK,THROW,BURN,TAKE,LEAVE,GIVE,KILL,EXAMINE,THREAT,BREAK,DRINK,OPEN
3440 REM
3450 REM ♦♦♦ ACTIONS ♦♦♦
3460 DATA 23,24,26,27,2<,2=,2D,2E,33,34O,34I,34J,44,52,5C,64O,66I,"6:8","6:A",6<M,6=N,6>N,6@A,6GT,69L,6>S,78,79,7A,86,84,83,8M9,99L,"9:8",9@A,"9:A",":QB",";?",<E,=O,H>,HF,IJ5,IM
3470 DATA >,?,@,A,B,C,D,E,F,G
3480 DATA 00,00,00,00,00,00,00,00
3490 DATA 01,01,01,FF,10,10,10,FF
3500 DATA 18,18,18,18,18,18,18,18
3510 DATA 18,18,3C,5A,99,18,24,24
3520 DATA 02,02,02,02,3E,3E,22,22
3530 DATA 00,81,FF,FF,02,06,00,00
3540 DATA FF,FF,FF,FF,FF,FF,FF,FF
3550 DATA 08,28,3A,7A,7E,7E,3E,1C
3560 DATA 07,0F,05,07,07,00,00,00
3570 DATA 18,18,18,18,18,18,18,18
3580 DATA 18,3C,7E,FF,E7,C3,C3,C3
3590 DATA 06,0E,1F,7D,DF,F6,BB,EF
3600 DATA 18,18,3C,5A,99,18,24,24
3610 DATA 00,00,00,00,00,00,00,00
3620 DATA 18,18,3C,5A,99,18,24,24
3630 DATA 00,00,00,00,00,00,00,00
3640 DATA E6,E6,E6,E6,E6,E6,E6,E6
3650 DATA 10,40,10,40,10,40,10,40
3660 DATA 10,D0,10,10,10,10,10,10
3670 DATA E0,E0,E0,E0,F0,E0,E0,E0
3680 DATA 10,10,10,C0,10,10,10,10
3690 DATA 10,10,10,10,10,10,10,10
3700 DATA 60,60,60,80,80,80,90,90
3710 DATA 10,10,10,10,10,10,10,10
3720 DATA 70,70,70,70,70,70,70,70
3730 DATA 90,D0,80,60,F1,F1,F1,F1
3740 DATA 90,90,90,90,91,91,91,91
3750 DATA 10,D0,F0,F0,F0,F0,F0,F0
3760 DATA 00,00,00,00,00,00,00,00
3770 DATA F0,60,10,F0,10,F0,10,F0
